DFPlayer Mini

DF Player Mini Commands (after Ype Brada)

DF Player mini command discovery

[This] program is meant to discover all the possibilities of the command structure of the DFPlayer mini. No special libraries are needed. Program is very easy to understand and can be the basis for your own mp3 player sketch.

Note: Commands are not always correctly described in the manual. I tried to fix it, but there is still something to do. The commands recoverd so far are listed below.

Use of sketch: Enter three ([comma] separated) decimal numbers in the Serial Monitor with no end of line character.

• First number : Command
• Second number: First (High Byte) parameter
• Third number : Second (Low Byte) parameter

E.g.: 3,0,1 will play the first track on the TF card

Very important: Use serial 1KΩ resistors or a level shifter between module RX and TX and Arduino to suppress noise

• Connect Sound module board RX to Arduino pin 11 (via 1KΩ resistor)
• Connect Sound module board TX to Arduino pin 10 (via 1KΩ resistor)
• Connect Sound module board Vcc to Arduino Vin when powered via USB (preferably 3.0) else use seperate 5V power supply
• Connect Sound module board GND to Arduino GND

General DF Player mini command structure

Checksum calculation: Checksum = -Sum(byte(1..6)) (2 bytes, notice minus sign!)

Commands

Key to following tables:

• Status column: * ⇒ Confirmed command; ? ⇒ Unknown, not clear or not validated
• Parameters columns: X ⇒ Value not used (set to zero?)

Commands without returned parameters

Commands with returned parameters

Additional info can be found on the DFRobot site, but is not very reliable. Additional info: http://www.dfrobot.com/index.php?route=product/product&product;_id=1121

Source Code

#include "SoftwareSerial.h"
# define Start_Byte 0x7E
# define Version_Byte 0xFF
# define Command_Length 0x06
# define End_Byte 0xEF
# define Acknowledge 0x00 //Returns info with command 0x41 [0x01: info, 0x00: no info]

SoftwareSerial mySerial(10, 11);    // RX pin = 10, TX pin = 11

void setup () {
  Serial.begin(9600);
  mySerial.begin (9600);
  execute_CMD(0x3F, 0, 0); // Send request for initialization parameters
  while (mySerial.available()<10) // Wait until initialization parameters are received (10 bytes)
  delay(30); // Pretty long delays between succesive commands needed (not always the same)
  // Initialize sound to very low volume. Adept according used speaker and wanted volume
  execute_CMD(0x06, 0, 5); // Set the volume (0x00~0x30)
}

void loop () {
  if (Serial.available())
  {
    // Input Serial monitor: Command and the two parameters in decimal numbers (NOT HEX)
    // E.g. 3,0,1 (or 3 0 1 or 3;0;1) will play first track on the TF-card
    byte Command = Serial.parseInt();
    byte Parameter1 = Serial.parseInt();
    byte Parameter2 = Serial.parseInt();
    // Write the input at the screen
    Serial.print("Command : 0x");if (Command < 16) Serial.print("0"); Serial.print(Command, HEX);
    Serial.print("("); Serial.print(Command, DEC);
    Serial.print("); Parameter: 0x");if (Parameter1 < 16) Serial.print("0");Serial.print(Parameter1, HEX);
    Serial.print("("); Serial.print(Parameter1, DEC);
    Serial.print("), 0x");if (Parameter2 < 16) Serial.print("0");Serial.print(Parameter2, HEX);
    Serial.print("("); Serial.print(Parameter2, DEC);Serial.println(")");
    // Excecute the entered command and parameters
    execute_CMD(Command, Parameter1, Parameter2);
  }

  if (mySerial.available()>=10)
  {
    // There is at least 1 returned message (10 bytes each)

    // Read the returned code
    byte Returned[10];
    for (byte k=0; k<10; k++)
      Returned[k] = mySerial.read();
    // Wtite the returned code at the screen
    Serial.print("Returned: 0x"); if (Returned[3] < 16) Serial.print("0"); Serial.print(Returned[3],HEX);
    Serial.print("("); Serial.print(Returned[3], DEC);
    Serial.print("); Parameter: 0x"); if (Returned[5] < 16) Serial.print("0"); Serial.print(Returned[5],HEX);
    Serial.print("("); Serial.print(Returned[5], DEC);
    Serial.print("), 0x"); if (Returned[6] < 16) Serial.print("0"); Serial.print(Returned[6],HEX);
    Serial.print("("); Serial.print(Returned[6], DEC); Serial.println(")");
  }
}

void execute_CMD(byte CMD, byte Par1, byte Par2)
  // Excecute the command and parameters
{
  // Calculate the checksum (2 bytes)
  word checksum = -(Version_Byte + Command_Length + CMD + Acknowledge + Par1 + Par2);
  // Build the command line
  byte Command_line[10] = { Start_Byte, Version_Byte, Command_Length, CMD, Acknowledge,
      Par1, Par2, highByte(checksum), lowByte(checksum), End_Byte};
  //Send the command line to the module
  for (byte k=0; k<10; k++)
  {
    mySerial.write( Command_line[k]);
  }
}